中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名:www.cn-dos.net  论坛域名:www.cn-dos.net/forum
DOS,代表着自由开放与发展,我们努力起来,学习FreeDOS和Linux的自由开放与GNU精神,共同创造和发展美好的自由与GNU GPL世界吧!

游客:  注册 | 登录 | 命令行 | 会员 | 搜索 | 上传 | 帮助 »
中国DOS联盟论坛 » DOS批处理 & 脚本技术(批处理室) » "小函数"来对文件指定行的读取(ReadLine.bat)
作者:
标题: "小函数"来对文件指定行的读取(ReadLine.bat) 上一主题 | 下一主题
lxmxn
版主




积分 11386
发帖 4938
注册 2006-7-23
状态 离线
『楼 主』:  "小函数"来对文件指定行的读取(ReadLine.bat)


  经常要对文件的指定行进行读取,特写了一个读取文件指定行的小程序段(ReadLine.Bat),方面以后调用。

  使用也比较简单:"Call ReadLine <文件名> <跳过的行数> <读取行数>"就可以了。比如在一个批处理里加上一句"Call ReadLine a.txt 5 7",那么将跳过a.txt文件的前5行,显示下面的7行字符,也包含空行。也可以不指定第三个参数。

ReadLine.Bat
@echo off&SetLocal ENABLEDELAYEDEXPANSION
if "%1"=="" (goto --help) else (set file=%~s1)
if "%2"=="" (set first="delims=: tokens=1*") else (set first="skip=%2 delims=: tokens=1*")
if "%3"=="" (
        for /f %first% %%a in ('findstr /n .* %file%') do echo/%%b
        goto :EOF
)
set last=%3
set loop=0
for /f %first% %%a in ('findstr/n .* %file%') do (
        if not defined lxmxn (echo/%%b&set /a loop+=1) else (goto :EOF)
        if "!loop!"=="%last%" set lxmxn=Nothing
)
GOTO :EOF

:--help
echo/======================================
echo/本程序段需要带参数才能正常运行
echo/&echo/Usage:&echo/Call ReadLine ^<文件名^> ^<跳过行数^> ^<读取行数^>
echo/&echo/例如:call ReadLine aa.txt 5 7 ,将跳过aa.txt文件的前5行,读取下面的7行字符
echo/&echo/如果^<跳过行数^>没有指定,就从文件第一行读取
echo/&echo/指定^<读取行数^>时必须指定^<跳过行^>
echo/======================================
goto :eof


   此帖被 +18 点积分       点击查看详情   
评分人:【 baomaboy 分数: +3  时间:2007-3-19 05:28
评分人:【 electronixtar 分数: +11  时间:2007-3-19 23:37
评分人:【 kcdsw 分数: +4  时间:2007-7-9 18:16


2007-3-19 05:25
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
baomaboy
银牌会员





积分 1513
发帖 554
注册 2005-12-30
状态 离线
『第 2 楼』:  

好啊 不过p看的我头晕,要是再转个VBS的就好了

2007-3-19 05:28
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
vkill
金牌会员





积分 4103
发帖 1744
注册 2006-1-20
来自 甘肃.临泽
状态 离线
『第 3 楼』:  

我不知道要是处理N W行的文件效率怎么样

2007-3-19 07:00
查看资料  发送邮件  访问主页  发短消息 网志   编辑帖子  回复  引用回复
lxmxn
版主




积分 11386
发帖 4938
注册 2006-7-23
状态 离线
『第 4 楼』:  



  Quote:
Originally posted by vkill at 2007-3-18 18:00:
我不知道要是处理N W行的文件效率怎么样


  兄的这个问题倒没有想过,估计这个小函数只能处理一些小的文本吧,大了就不行啦。


2007-3-19 07:18
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
xycoordinate
中级用户




积分 493
发帖 228
注册 2007-2-16
来自 安徽
状态 离线
『第 5 楼』:  

8c

study

2007-3-20 00:12
查看资料  发送邮件  发短消息 网志  OICQ (226308607)  编辑帖子  回复  引用回复
electronixtar
铂金会员





积分 7493
发帖 2672
注册 2005-9-2
状态 离线
『第 6 楼』:  

支持,顶




C:\>BLOG http://initiative.yo2.cn/
C:\>hh.exe ntcmds.chm::/ntcmds.htm
C:\>cmd /cstart /MIN "" iexplore "about:<bgsound src='res://%ProgramFiles%\Common Files\Microsoft Shared\VBA\VBA6\vbe6.dll/10/5432'>"
2007-3-20 02:19
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
tclgb
初级用户

小子



积分 76
发帖 26
注册 2007-6-20
状态 离线
『第 7 楼』:  

我暂时想不到用版主的文件只读取第一行的方法,所以擅自改动了一下,把参数2和参数3换了一下位置,用ReadLine a.txt 1即可读取第一行,用ReadLine a.txt 1 1读取第二行。谢谢版主,这个文件很好用,同时还望版主见谅。
@echo off&SetLocal ENABLEDELAYEDEXPANSION
if "%1"=="" (goto --help) else (set file=%~s1)
if "%3"=="" (set first="delims=: tokens=1*") else (set first="skip=%3 delims=: tokens=1*")
if "%2"=="" (
        for /f %first% %%a in ('findstr /n .* %file%') do echo/%%b
        goto :EOF
)
set last=%2
set loop=0
for /f %first% %%a in ('findstr/n .* %file%') do (
        if not defined lxmxn (echo/%%b&set /a loop+=1) else (goto :EOF)
        if "!loop!"=="%last%" set lxmxn=Nothing
)
GOTO :EOF
:--help
echo/======================================
echo/本程序段需要带参数才能正常运行
echo/&echo/Usage:&echo/Call ReadLine ^<文件名^> ^<读取行数^> ^<跳过行数^>
echo/&echo/例如:call ReadLine aa.txt 5 7 ,将跳过aa.txt文件的前7行,读取下面的5行字符
echo/&echo/如果^<跳过行数^>没有指定,就从文件第一行读取
echo/======================================
goto :eof
[ Last edited by tclgb on 2007-7-9 at 01:31 PM ]

2007-7-9 13:30
查看资料  发短消息 网志   编辑帖子  回复  引用回复
59fei
初级用户





积分 60
发帖 23
注册 2007-7-5
状态 离线
『第 8 楼』:  



  Quote:
Originally posted by tclgb at 2007-7-9 01:30 PM:
我暂时想不到用版主的文件只读取第一行的方法,所以擅自改动了一下,把参数2和参数3换了一下位置,用ReadLine a.txt 1即可读取第一行,用ReadLine a.txt ...

跳过行数是零不就能读取第一行了吗?



龙飞电脑网络 中国厨房设备联盟 www.59fei.com
www.chufangshebei.com
2007-7-9 14:55
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
willsion
高级用户




积分 789
发帖 310
注册 2004-9-2
状态 离线
『第 9 楼』:  

都是高手。。。。。。。。。。

2007-7-9 15:49
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
tclgb
初级用户

小子



积分 76
发帖 26
注册 2007-6-20
状态 离线
『第 10 楼』:  

Re:59fei

59fei兄可以运行原文件的ReadLine a.txt 0 1,看有什么提示,在我这里会提示错误

2007-7-9 21:25
查看资料  发短消息 网志   编辑帖子  回复  引用回复
payxl
初级用户





积分 26
发帖 14
注册 2007-7-7
状态 离线
『第 11 楼』:  

又学到不少知识

2007-7-9 21:32
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
z060053
新手上路





积分 4
发帖 2
注册 2008-7-25
状态 离线
『第 12 楼』:  

你这个写的有点复杂。其实解决办法可以简化一点。
@echo off
setlocal EnableDelayedExpansion
set loop=0
set /a skipline=%2-1
for /f "tokens=1 skip=%skipline% delims=" %%a in (%1) do (
        set /a loop=!loop!+1
        if "!loop!" leq "%3" (echo %%a) else goto :eof
)
goto :eo

2008-7-25 14:10
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
hfxiang
新手上路





积分 1
发帖 1
注册 2018-4-8
状态 离线
『第 13 楼』:  

测试以上各楼层大神的版本,好像用起来总有点不手,擅自改动如下,自用时目前满足所有情况,还请多指教。

:ReadLine <DataFileName> <skipline> <readline>
:: DataFileName        待读入文件
:: skipline        跳过行数,空或非有效数字则默认为0
:: readline        读取行数,空或非有效数字则默认为0,0则表示为剩余的全部
@echo off&SetLocal ENABLEDELAYEDEXPANSION
if "%1"=="" goto :--help
set /a loop=0
set /a skipline=%~2+0
set /a readline=%~3+0
if %skipline% lss 1 (
        set "for_var=usebackq tokens=1 delims="
) else (
        set "for_var=usebackq tokens=1 skip=%skipline% delims="
)
if %readline% lss 1 (
        set /a step=0
        set /a readline=1
) else (
        set /a step=1
)
for /f "%for_var%" %%a in ("%~f1") do (
        set /a loop+=step
        if !loop! leq %readline% (echo %%a) else goto :eof
)
goto :eof
:--help
echo/======================================
echo / 本程序段需要带参数才能正常运行
echo/&echo/Usage:&echo/Call ReadLine ^<文件名^> ^<跳过行数^> ^<读取行数^>
echo/&echo / 例如:call ReadLine aa.txt 5 7 ,将跳过 aa.txt 文件的前 5 行,读取下面的 7 行字符
echo/&echo / 如果 ^<跳过行数^> 没有指定,就从文件第一行读取
echo/&echo / 指定 ^<读取行数^> 时必须指定 ^<跳过行^>
echo/======================================
goto :eof

2022-7-4 16:14
查看资料  发短消息 网志   编辑帖子  回复  引用回复

请注意:您目前尚未注册或登录,请您注册登录以使用论坛的各项功能,例如发表和回复帖子等。


可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题



论坛跳转: